Ultra Gameplayers 101/Ultra Game Players Magazine, No. 101 - September 1997 (Imagine Publishing, Inc.)(1997).iso/pc/new_ugp.dxr/00211_Game Manager Class.ls

Text File | 1997-07-10 | 1.8 KB | 61 lines

property gameList, memberNum, normalColor, hiliteColor, killList

on new me, paramList
  set killList to []
  set gameList to getProp(paramList, #gameList)
  set memberNum to getProp(paramList, #memberID)
  set normalColor to getaProp(paramList, #normalColor)
  set hiliteColor to getaProp(paramList, #hiliteColor)
  if stringp(memberNum) then
    set memberNum to the number of member memberNum
  end if
  if (memberNum > 0) and (normalColor >= 0) then
    set the foreColor of member memberNum to translateColor(normalColor)
  end if
  set the stageColor to the stageColor
  return me
end

on TurnOn me, spritenum, lineNum
  if memberNum <= 0 then
    set memberNum to the memberNum of sprite spritenum
  end if
  set currName to line lineNum of the text of member memberNum
  set currGame to 0
  repeat with game in gameList
    if the name of game = currName then
      set currGame to game
      exit repeat
    end if
  end repeat
  if objectp(currGame) then
    set the foreColor of member memberNum to translateColor(normalColor)
    if isMac() then
      if lineNum = the number of lines in the text of the member of sprite spritenum then
        set the text of the member of sprite spritenum to the text of the member of sprite spritenum & RETURN
      end if
    end if
    set the foreColor of line lineNum of member memberNum to translateColor(hiliteColor)
    set the stageColor to the stageColor
    DoGame(currGame)
  else
    set nameList to "|"
    repeat with game in gameList
      set nameList to nameList & the name of game & "|"
    end repeat
    put "No game match: name:" && currName && "game list:" && nameList
  end if
end

on TurnOff me
end

on dispose me
  set memberNum to 0
  set normalColor to 0
  set hiliteColor to 0
  set gameList to []
  ClearObjectList(killList)
  set killList to []
end